91 lines
2.8 KiB
Bash
91 lines
2.8 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgbase=notmuch
|
|
pkgname=('notmuch' 'notmuch-vim' 'notmuch-runtime')
|
|
pkgver=0.37
|
|
pkgrel=2
|
|
arch=('i686' 'x86_64')
|
|
url="https://notmuchmail.org/"
|
|
license=('GPL-3')
|
|
makedepends=('python' 'python-setuptools' 'python-sphinx' 'python-cffi'
|
|
'gnupg-stable' 'ruby' 'pkgconfig' 'xapian-core' 'gmime3' 'talloc' 'sfsexp')
|
|
options=(!makeflags)
|
|
source=("https://notmuchmail.org/releases/${pkgname}-${pkgver}.tar.xz")
|
|
sha512sums=('31cac1ff03b139b18a4fec5e29907ba0e3a965f0a7bf5f2f2b0f75980f9663173745be854e83943f344a09cdb7f5615fa48218e327c4ade7a55b3a22b2a9c45e')
|
|
|
|
build() {
|
|
cd "$srcdir/$pkgbase-$pkgver"
|
|
|
|
./configure \
|
|
--prefix=/usr \
|
|
--sysconfdir=/etc \
|
|
--includedir=/usr/include \
|
|
--zshcompletiondir=/usr/share/zsh/site-functions
|
|
make
|
|
|
|
make -C "contrib/${pkgbase}-mutt"
|
|
|
|
make ruby-bindings
|
|
|
|
cd "$srcdir/$pkgbase-$pkgver/bindings/python"
|
|
python setup.py build
|
|
|
|
cd "$srcdir/$pkgbase-$pkgver/bindings/python-cffi"
|
|
python setup.py build
|
|
}
|
|
|
|
package_notmuch-runtime(){
|
|
pkgdesc="Runtime for notmuch and notmuch-mutt"
|
|
depends=('xapian-core' 'gmime3' 'talloc' 'sfsexp')
|
|
|
|
cd "$srcdir/$pkgbase-$pkgver"
|
|
|
|
make DESTDIR="$pkgdir/" LIBDIR_IN_LDCONFIG=0 WITH_EMACS=0 install
|
|
make DESTDIR="$pkgdir/" WITH_BASH=1 install-completion
|
|
|
|
# install manpages
|
|
make DESTDIR="$pkgdir" install-man
|
|
|
|
# this is provided both with and without a statically included library
|
|
install -Dm755 notmuch-shared "$pkgdir/usr/bin/notmuch"
|
|
|
|
# license
|
|
install -Dm644 "$srcdir/$pkgbase-$pkgver/COPYING-GPL-3" -t "$pkgdir/usr/share/licenses/$pkgname"
|
|
}
|
|
|
|
package_notmuch-vim(){
|
|
pkgdesc="Vim plugins for notmuch"
|
|
depends=('notmuch-runtime' 'ruby')
|
|
optdepends=('elinks: for previewing html mail')
|
|
|
|
make -C "$srcdir/$pkgbase-$pkgver/vim" DESTDIR="$pkgdir" prefix="/usr/share/vim/vimfiles" install
|
|
|
|
# license
|
|
install -Dm644 "$srcdir/$pkgbase-$pkgver/COPYING-GPL-3" -t "$pkgdir/usr/share/licenses/$pkgname"
|
|
}
|
|
|
|
package_notmuch(){
|
|
pkgdesc="Notmuch is not much of an email program"
|
|
depends=('notmuch-runtime')
|
|
optdepends=('vim: for using the vim interface'
|
|
'python-cffi: for using the python-cffi bindings'
|
|
'ruby: for using the ruby bindings'
|
|
'gnupg-stable: for email encryption')
|
|
|
|
cd "$srcdir/$pkgbase-$pkgver"
|
|
|
|
# install ruby bindings
|
|
sed -i 's:INSTALL = .*[^D]$:& -D:' bindings/ruby/Makefile
|
|
make -C bindings/ruby exec_prefix="$pkgdir"/usr install
|
|
|
|
# install python bindings
|
|
cd "$srcdir/$pkgbase-$pkgver/bindings/python"
|
|
python setup.py install --root="$pkgdir" --optimize=1
|
|
|
|
cd "$srcdir/$pkgbase-$pkgver/bindings/python-cffi"
|
|
python setup.py install --root="$pkgdir" --optimize=1
|
|
|
|
# license
|
|
install -Dm644 "$srcdir/$pkgbase-$pkgver/COPYING-GPL-3" -t "$pkgdir/usr/share/licenses/$pkgname"
|
|
}
|