92 lines
3.0 KiB
Bash
92 lines
3.0 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgbase=gutenprint
|
|
pkgname=('gutenprint' 'foomatic-db-gutenprint-ppds')
|
|
pkgver=5.3.3
|
|
_debver=$pkgver
|
|
_debrel=5
|
|
pkgrel=2
|
|
pkgdesc="Top quality printer drivers for POSIX systems"
|
|
arch=(i686 x86_64)
|
|
license=('GPL-2')
|
|
url='https://gimp-print.sourceforge.io/'
|
|
makedepends=('gimp' 'gtk2' 'cups' 'ghostscript' 'quilt'
|
|
'dialog' 'doxygen' 'texi2html')
|
|
source=("https://downloads.sourceforge.net/gimp-print/$pkgname-$pkgver.tar.xz"
|
|
"https://deb.debian.org/debian/pool/main/g/$pkgname/${pkgname}_${_debver}-${_debrel}.debian.tar.xz")
|
|
options=('!emptydirs')
|
|
sha512sums=('d2c47eb4ccc3c46ccb2f1042682edf7443f5c57439ead72f49ecd10537cf967251bacf7ca7da29fb8dceecc7eebd55ed021f2594ff9fb6509bab543fab1dc8d6'
|
|
'3cdaea8e27e4b0d83a64f79072ecd1acac111e66f4fb8acd64e9a7805d95c41776eb2dabb1755bbca9272cd42e17403c3cdc535e0899fa337578093e5fc87dba')
|
|
|
|
prepare(){
|
|
cd "${pkgbase}"-${pkgver}
|
|
|
|
if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
|
|
# Debian patches
|
|
export QUILT_PATCHES=debian/patches
|
|
export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
|
|
export QUILT_DIFF_ARGS='--no-timestamps'
|
|
|
|
mv "$srcdir"/debian .
|
|
|
|
quilt push -av
|
|
fi
|
|
autoreconf -vfi
|
|
}
|
|
|
|
build() {
|
|
cd "${pkgbase}"-${pkgver}
|
|
./configure --prefix=/usr \
|
|
--disable-rpath \
|
|
--enable-samples \
|
|
--disable-static \
|
|
--disable-static-genppd \
|
|
--enable-cups-ppds \
|
|
--enable-simplified-cups-ppds=only \
|
|
--enable-translated-cups-ppds \
|
|
--enable-globalized-cups-ppds #--help
|
|
|
|
# globalized ppds -> put all translations into one ppd file
|
|
# enable translated cups ppds grows size 9,5MB -> 156MB
|
|
# simplified cups ppds (yes, no, only) - only offer basic paper sizes, not all options
|
|
# 4,3MB (only), 17MB (both) -> translated 41MB simpl., 165MB, 231MB both
|
|
|
|
sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
|
|
make
|
|
}
|
|
|
|
package_gutenprint() {
|
|
pkgdesc="Top quality printer drivers for POSIX systems"
|
|
install=gutenprint.install
|
|
depends=('cups' 'cups-filters')
|
|
optdepends=('gimp: adds gutenprint plugin to gimp'
|
|
'libusb: required for drivers that depend on gutenprint52usb backend'
|
|
'foomatic-db-gutenprint-ppds: prebuilt ppd files'
|
|
'perl: to run cups-genppdupdate')
|
|
replaces=('gimp-print')
|
|
options=('!emptydirs')
|
|
|
|
cd "${pkgname}"-${pkgver}
|
|
make DESTDIR="${pkgdir}" install
|
|
|
|
# split out files
|
|
mkdir "$srcdir"/tmp_foomatic-db-gutenprint-ppds
|
|
|
|
mv "${pkgdir}"/usr/share/cups/model "$srcdir"/tmp_foomatic-db-gutenprint-ppds/
|
|
|
|
# cleanup
|
|
rm -rf "${pkgdir}"/usr/share/foomatic
|
|
rm -rf "${pkgdir}"/etc
|
|
install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
|
|
}
|
|
|
|
package_foomatic-db-gutenprint-ppds() {
|
|
pkgdesc="simplified prebuilt ppd files"
|
|
optdepends=('cups: to use cups printer spooler(recommended)')
|
|
|
|
cd "${pkgbase}"-${pkgver}
|
|
mkdir -p "${pkgdir}"/usr/share/cups
|
|
mv "$srcdir"/tmp_foomatic-db-gutenprint-ppds/* "${pkgdir}"/usr/share/cups/
|
|
install -Dm644 COPYING -t $pkgdir/usr/share/licenses/$pkgname
|
|
}
|