66 lines
2.0 KiB
Bash
66 lines
2.0 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgname=libcurl3-gnutls
|
|
pkgver=7.72.0
|
|
pkgrel=2
|
|
pkgdesc="An URL retrieval library (linked against gnutls) with libcurl3 versioned symbols"
|
|
arch=('i686' 'x86_64')
|
|
url='https://curl.haxx.se'
|
|
license=('Expat')
|
|
depends=('curl' 'glibc' 'gnutls' 'libpsl' 'nettle' 'zlib' 'libssh2')
|
|
options=('strip')
|
|
conflicts=('libcurl-gnutls')
|
|
provides=('libcurl-gnutls')
|
|
source=("https://curl.haxx.se/download/curl-${pkgver}.tar.gz"{,.asc}
|
|
"03_keep_symbols_compat.patch"
|
|
"CVE-2023-38545.patch")
|
|
sha512sums=('f1946394595baa2b2889c4fed5e8745036cecfe9c425010c41fbc4baa71ffd7ff3e78289dd7ee14f0c74c482056838e5408d63f9ee9ee06c31ed920282f08507'
|
|
'SKIP'
|
|
'596c227bb5ede8182831c5c92b3ac7b74b770f51fae99277e2aabb02d38b7a5d4d06003731042ab5403ca89e719827d7080c3a179e29ef08b41a1993a7788a33'
|
|
'6e4303f35589d36053d38192bfafdc4fdbb91e491f7ef4bac7193a7ddc0958242d10ffe92c1b3a04bb474bb81db5435619f0c76c1830c0e769465f81a1246c29')
|
|
validpgpkeys=('27EDEAF22F3ABCEB50DB9A125CC908FDB71E12C2') # Daniel Stenberg <daniel@haxx.se>
|
|
|
|
prepare() {
|
|
cd curl-${pkgver}
|
|
|
|
patch -p1 < ${srcdir}/03_keep_symbols_compat.patch
|
|
patch -p1 < ${srcdir}/CVE-2023-38545.patch
|
|
}
|
|
|
|
build() {
|
|
cd curl-${pkgver}
|
|
|
|
./configure \
|
|
--prefix='/usr' \
|
|
--disable-ldap \
|
|
--disable-ldaps \
|
|
--disable-manual \
|
|
--enable-versioned-symbols \
|
|
--enable-ipv6 \
|
|
--enable-threaded-resolver \
|
|
--without-gssapi \
|
|
--with-libssh2 \
|
|
--without-libidn \
|
|
--without-ssl \
|
|
--with-gnutls='/usr' \
|
|
--with-random='/dev/urandom' \
|
|
--with-ca-bundle='/etc/ssl/certs/ca-certificates.crt'
|
|
|
|
make -C lib
|
|
}
|
|
|
|
package() {
|
|
cd curl-${pkgver}
|
|
|
|
make -C lib DESTDIR="${pkgdir}" install
|
|
|
|
mv "${pkgdir}"/usr/lib/libcurl{,-gnutls}.so.4.6.0
|
|
rm "${pkgdir}"/usr/lib/libcurl.{a,so}*
|
|
for version in 3 4 4.0.0 4.1.0 4.2.0 4.3.0 4.4.0 4.5.0; do
|
|
ln -s libcurl-gnutls.so.4.6.0 "${pkgdir}"/usr/lib/libcurl-gnutls.so.${version}
|
|
done
|
|
|
|
# license
|
|
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
|
|
}
|