70 lines
2.5 KiB
Bash
70 lines
2.5 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgname=dnsmasq
|
|
pkgver=2.85
|
|
pkgrel=1
|
|
pkgdesc="Lightweight, easy to configure DNS forwarder and DHCP server"
|
|
url="http://www.thekelleys.org.uk/dnsmasq/doc.html"
|
|
arch=('i686' 'x86_64')
|
|
license=('GPL-2')
|
|
depends=('glibc' 'gmp' 'libidn' 'libnetfilter_conntrack' 'nettle')
|
|
makedepends=('gettext-tiny')
|
|
optdepends=('logger: message logging support')
|
|
backup=('etc/dnsmasq.conf')
|
|
install=$pkgname.install
|
|
source=("https://www.thekelleys.org.uk/$pkgname/$pkgname-$pkgver.tar.xz"{,.asc}
|
|
'0001-Handle-binding-upstream-servers-to-an-interface.patch'
|
|
'remove-dbus.patch'
|
|
'dnsmasq.initd'
|
|
'dnsmasq.run')
|
|
sha512sums=('8beefe76b46f7d561f40d0900ba68b260a199cb62ab5b653746e3a1104c04fb8899b9e7a160a1be4fe8782bfb1607b556e9ffb9c25c4e99653e4bc74fcc03b09'
|
|
'SKIP'
|
|
'e00f1f7ac6c9ccab3bcc5c605cf7c772f673824f07993315e0aa17179d2e4ae234aad6780fddaa026a924610ba921fc5dc2d1c03e4e7cd28bc5461ba5d989e1e'
|
|
'3c49837d918bc33a4660148a23fc4a23e00ee01a0870bed89e54e537ce0601c31e694ef46acf16cb9e9444a62294455f40c33cda4c801b79c730ecbfb3105b2b'
|
|
'8cf3092fcc095c307009d12a150883386bd1b0dcdc9cac0c5d1a24df80405bdba89497c88a1e2ac1e1259d3684bc6a6089f477a4f735fb8d0f4edcc29d6e9a06'
|
|
'05586daa918401c036fbf27f79c8883fc19de35f5feb2a9373eba90ed5302f615439cd117be55f0e4db638cd879ce453ef664503970952bf07ed1a8468fcb918')
|
|
validpgpkeys=('D6EACBD6EE46B834248D111215CDDA6AE19135A2') # Simon Kelley
|
|
|
|
_build_copts="-DHAVE_DNSSEC -DHAVE_IDN -DHAVE_CONNTRACK"
|
|
|
|
prepare() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
# Handle binding upstream servers to an interface
|
|
patch -Np1 -i "$srcdir/0001-Handle-binding-upstream-servers-to-an-interface.patch"
|
|
patch -Np1 -i "$srcdir/remove-dbus.patch"
|
|
}
|
|
|
|
build() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
make \
|
|
CFLAGS="$CPPFLAGS $CFLAGS" \
|
|
LDFLAGS="$LDFLAGS" \
|
|
PREFIX=/usr \
|
|
COPTS="$_build_copts" \
|
|
all-i18n
|
|
}
|
|
|
|
package() {
|
|
cd "$pkgname-$pkgver"
|
|
|
|
# need to pass COPTS here to avoid rebuilding the binary.
|
|
make \
|
|
COPTS="$_build_copts" \
|
|
PREFIX=/usr DESTDIR="$pkgdir" \
|
|
install install-i18n
|
|
|
|
install -Dm644 COPYING "$pkgdir"/usr/share/licenses/$pkgname/COPYING
|
|
|
|
install -Dm644 "dnsmasq.conf.example" "$pkgdir/etc/dnsmasq.conf"
|
|
install -Dm755 "$srcdir/dnsmasq.initd" "$pkgdir/etc/init.d/dnsmasq"
|
|
install -Dm755 "$srcdir/dnsmasq.run" "$pkgdir/etc/sv/dnsmasq/run"
|
|
|
|
# DNSSEC setup
|
|
sed -i 's,%%PREFIX%%,/usr,' "$pkgdir"/etc/dnsmasq.conf
|
|
install -Dm644 "trust-anchors.conf" "$pkgdir"/usr/share/dnsmasq/trust-anchors.conf
|
|
}
|
|
|
|
# vim: ts=2 sw=2 et ft=sh
|