45 lines
1.6 KiB
Bash
45 lines
1.6 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgbase=python-ndg-httpsclient
|
|
pkgname=(python-ndg-httpsclient tauthon-ndg-httpsclient)
|
|
_pkgname=ndg_httpsclient
|
|
pkgver=0.5.1
|
|
pkgrel=2
|
|
pkgdesc="Provides enhanced HTTPS support for httplib and urllib2 using PyOpenSSL"
|
|
arch=('any')
|
|
url='https://pypi.python.org/pypi/ndg-httpsclient'
|
|
license=('Modified-BSD')
|
|
makedepends=('tauthon-setuptools' 'tauthon-pyopenssl' 'tauthon-pyasn1' 'python-setuptools' 'python-pyopenssl' 'python-pyasn1')
|
|
options=(!emptydirs)
|
|
source=("https://files.pythonhosted.org/packages/source/n/ndg-httpsclient/${_pkgname}-${pkgver}.tar.gz")
|
|
sha512sums=('b2b4c1b1df87ea1a94811b9ae831e7bf32af27258f487fd5ec319e0e6e0d79dfdb1f7bfadaf397d0693a8a7f0720df170a7fc946aaf10c82e3957ac5464f672e')
|
|
|
|
build() {
|
|
cd "$srcdir"/$_pkgname-$pkgver
|
|
|
|
rm -rf ../buildpython; mkdir ../buildpython
|
|
python setup.py build -b ../buildpython
|
|
|
|
rm -rf ../buildtauthon; mkdir ../buildtauthon
|
|
tauthon setup.py build -b ../buildtauthon
|
|
}
|
|
|
|
package_python-ndg-httpsclient() {
|
|
depends=('python-pyopenssl' 'python-pyasn1')
|
|
|
|
cd "$srcdir"/$_pkgname-$pkgver
|
|
rm -rf build; ln -s ../buildpython build
|
|
python setup.py install --skip-build -O1 --root="$pkgdir"
|
|
install -Dm0644 ndg/httpsclient/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
}
|
|
|
|
package_tauthon-ndg-httpsclient() {
|
|
depends=('tauthon-pyopenssl' 'tauthon-pyasn1')
|
|
|
|
cd "$srcdir"/$_pkgname-$pkgver
|
|
rm -rf build; ln -s ../buildtauthon build
|
|
tauthon setup.py install --skip-build -O1 --root="$pkgdir"
|
|
install -Dm0644 ndg/httpsclient/LICENSE -t "$pkgdir"/usr/share/licenses/$pkgname
|
|
mv "$pkgdir"/usr/bin/ndg_httpclient{,-tauthon}
|
|
}
|