57 lines
2.2 KiB
Bash
57 lines
2.2 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgname=netsurf
|
|
pkgver=3.10
|
|
pkgrel=5
|
|
pkgdesc="Lightweight and fast web browser"
|
|
arch=('i686' 'x86_64')
|
|
url='https://www.netsurf-browser.org/'
|
|
license=('Expat' 'GPL-2')
|
|
depends=('bash' 'curl' 'gtk' 'libhubbub' 'libjpeg-turbo' 'libnsutils'
|
|
'libnsgif' 'libutf8proc' 'libwapcaplet' 'libdom')
|
|
makedepends=('check' 'net-tools' 'libcss' 'libnsbmp'
|
|
'libnsgif' 'nsgenbind' 'perl-html-parser' 'setconf' 'vim')
|
|
source=("https://download.netsurf-browser.org/netsurf/releases/source-full/netsurf-all-$pkgver.tar.gz"
|
|
"netsurf.sh"
|
|
"libre.patch")
|
|
sha512sums=('fc4c300eef07c540a7e07f8034db25b7e5fb731b5956029af2220f8638802aa38c055ad54b5683c14501aef9c22fb781b96613c16ae9a6996c3833ceede6f9bf'
|
|
'00f284e48c2a73600aa8428bf8283df086d020fcb175aae68201decd9a3043d3803bf0f05130c6fac5cbb046fecc6289c7e4396a7e6d75e46ffa09238e768248'
|
|
'0494589bcbfc2613fd83d4aed151515afdcc2433e3bccfdd10a15ee9d159e6a613f84440420ec1cbac5b8613ae479438af18c11ea0f9f45bb93c6dac9e024ee1')
|
|
|
|
prepare() {
|
|
cd "$pkgname-all-$pkgver"
|
|
# Remove nonfree engines
|
|
patch -Np1 -i "${srcdir}/libre.patch"
|
|
# Fix compilation issues
|
|
sed -i 's:libutf8proc/::;s:UTF8PROC_CCC_VIRAMA:UTF8PROC_BIDI_CLASS_EN:' netsurf/utils/idna.c
|
|
# Use "netsurf" as the name of the executable in /usr/bin
|
|
setconf netsurf/frontends/gtk/res/netsurf-gtk.desktop 'Exec=netsurf %u'
|
|
}
|
|
|
|
build() {
|
|
CFLAGS="$CFLAGS -w -Os -funroll-loops" \
|
|
make -C "$pkgname-all-$pkgver/$pkgname" \
|
|
NETSURF_UA_FORMAT_STRING='"NetSurf/%d.%d (%s; Hyperbola GNU/Linux-libre)"' \
|
|
TARGET=gtk3 \
|
|
LIBDIR=lib \
|
|
INCLUDEDIR=include \
|
|
PREFIX=/usr
|
|
}
|
|
|
|
package() {
|
|
make -C "$pkgname-all-$pkgver/$pkgname" \
|
|
TARGET=gtk3 \
|
|
LIBDIR=lib \
|
|
INCLUDEDIR=include \
|
|
DESTDIR="$pkgdir" \
|
|
PREFIX=/usr \
|
|
install
|
|
install -Dm755 $pkgname.sh "$pkgdir/usr/bin/$pkgname"
|
|
cd "$pkgname-all-$pkgver/$pkgname"
|
|
install -Dm644 frontends/gtk/res/$pkgname.xpm \
|
|
"$pkgdir/usr/share/pixmaps/$pkgname.xpm"
|
|
install -Dm644 frontends/gtk/res/$pkgname-gtk.desktop \
|
|
"$pkgdir/usr/share/applications/$pkgname.desktop"
|
|
install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
|
|
}
|