61 lines
2.3 KiB
Bash
61 lines
2.3 KiB
Bash
# Maintainer: Jesus E. <heckyel@riseup.net>
|
|
|
|
pkgname=lua
|
|
pkgver=5.3.5
|
|
_majorver=${pkgver%.*}
|
|
pkgrel=1
|
|
pkgdesc='Powerful lightweight programming language designed for extending applications'
|
|
arch=('i686' 'x86_64')
|
|
url='https://www.lua.org/'
|
|
depends=('readline')
|
|
license=('Expat')
|
|
options=('!emptydirs')
|
|
source=(https://www.lua.org/ftp/lua-$pkgver.tar.gz
|
|
liblua.so.patch
|
|
lua.pc
|
|
LICENSE)
|
|
sha512sums=('4f9516acc4659dfd0a9e911bfa00c0788f0ad9348e5724fe8fb17aac59e9c0060a64378f82be86f8534e49c6c013e7488ad17321bafcc787831d3d67406bd0f4'
|
|
'38fb153c0a12c2f6e93b728072d7c99f1776b9c25e48a06e3b6757a18fd7040002a935db2079723faa5eff86e50e15870257b1c3e69a9443001ac1d200d3d228'
|
|
'a3ae5f5c63a27956a2c69464cf966512be7404aef72d49b0b3b17e35999ceed04ec7be12ef19269f4cac908141b98dd5d16df9c238823fe0c1e068212914657a'
|
|
'7177faeef3d7699748d3523d7884f8037fc04be02a51bd3f0590de6ef074f723f2462a6fcc23c7625a7d8667247d62fa2b41cf94d0a8fd3f0df1e4a1b9ed336f')
|
|
|
|
prepare() {
|
|
cd lua-$pkgver
|
|
patch -p1 -i ../liblua.so.patch
|
|
|
|
sed "s/%VER%/$_majorver/g;s/%REL%/$pkgver/g" ../lua.pc > lua.pc
|
|
|
|
# Lua 5.3.4 has wrong release version in its Makefile. Fix it.
|
|
sed "s/^R= \$V.4/R= \$V.5/" -i Makefile
|
|
}
|
|
|
|
build() {
|
|
cd lua-$pkgver
|
|
|
|
# quite a lot of packages still use lua 5.1 API, enable 5.1 compat mode
|
|
make MYCFLAGS="$CFLAGS -fPIC -DLUA_COMPAT_5_2 -DLUA_COMPAT_5_1" MYLDFLAGS="$LDFLAGS" linux
|
|
}
|
|
|
|
package() {
|
|
cd lua-$pkgver
|
|
|
|
make \
|
|
TO_LIB="liblua.a liblua.so liblua.so.$_majorver liblua.so.$pkgver" \
|
|
INSTALL_DATA='cp -d' \
|
|
INSTALL_TOP="$pkgdir"/usr \
|
|
INSTALL_MAN="$pkgdir"/usr/share/man/man1 \
|
|
install
|
|
ln -sf /usr/bin/lua "$pkgdir"/usr/bin/lua$_majorver
|
|
ln -sf /usr/bin/luac "$pkgdir"/usr/bin/luac$_majorver
|
|
ln -sf /usr/lib/liblua.so.$pkgver "$pkgdir"/usr/lib/liblua$_majorver.so
|
|
|
|
install -Dm644 lua.pc "$pkgdir"/usr/lib/pkgconfig/${pkgname}53.pc
|
|
ln -sf ${pkgname}53.pc "$pkgdir"/usr/lib/pkgconfig/${pkgname}.pc
|
|
ln -sf ${pkgname}53.pc "$pkgdir"/usr/lib/pkgconfig/${pkgname}5.3.pc
|
|
ln -sf ${pkgname}53.pc "$pkgdir"/usr/lib/pkgconfig/${pkgname}-5.3.pc
|
|
|
|
install -d "$pkgdir"/usr/share/doc/$pkgname
|
|
install -m644 doc/*.{gif,png,css,html} "$pkgdir"/usr/share/doc/$pkgname
|
|
install -Dm644 ../LICENSE "$pkgdir"/usr/share/licenses/$pkgname/LICENSE
|
|
}
|