# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=zaz
pkgver=1.0.1
_debver=$pkgver
_debrel=1
pkgrel=1
pkgdesc="Puzzle game where the player has to arrange balls in triplets"
arch=('i686' 'x86_64')
url='https://sourceforge.net/projects/zaz/'
license=('GPL-3' 'CC-BY-SA-3.0')
depends=('ftgl' 'sdl' 'sdl_image' 'libvorbis' 'libtheora')
makedepends=('quilt')
groups=('games')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/z/zaz/zaz_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/z/zaz/zaz_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('c522fda00b1577d7b5c7e5dfa8d20f6fa9f8566215cb98f5e20c8f6fb94cee41342832053c583efe01560a42fa73be93b0783d4bacc49c0f31234211e1cb105d'
            '49e9e7d3149970c52bfebf8072ce08bc6fa25fa7b9bf90f4f1f78ee57ed34d8dc24f5fefd68bf35459ef79d402f6acaa539ed059802f64142eec195f0036560c')

prepare() {
  cd "$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf -vfi
}

build() {
  cd "$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --bindir=/usr/games \
    --datadir=/usr/share/games \
    --disable-splash
  make ZAZ_LIBS+=" -lvorbis -logg -lSDL -lvorbisfile -ltheora -ltheoradec -ltheoraenc"
}

package() {
  cd "$pkgname-$pkgver"

  make DESTDIR="$pkgdir/" install
  mv "$pkgdir/usr/share/games/"{applications,pixmaps} "$pkgdir/"usr/share

  install -Dm644 COPYING -t "$pkgdir"/usr/share/licenses/$pkgname
  install -Dm644 data/copyright.txt -t "$pkgdir"/usr/share/licenses/$pkgname
}