# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=yelp
pkgver=3.38.3
_debver=$pkgver
_debrel=1
pkgrel=4
pkgdesc="Help browser"
url='https://wiki.gnome.org/Apps/Yelp'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('webkitgtk' 'yelp-xsl' 'libxslt' 'xz' 'bzip2')
makedepends=('intltool' 'gettext-tiny' 'itstool' 'autoconf-archive' 'xenocara-server-xvfb' 'quilt')
source=("https://download.gnome.org/sources/$pkgname/${pkgver:0:4}/$pkgname-$pkgver.tar.xz"
        "https://deb.debian.org/debian/pool/main/y/yelp/yelp_$_debver-$_debrel.debian.tar.xz"
        "CVE-2025-3155.patch")
sha512sums=('7e4749b652fa60ab82a715f40be6b8e0430869ec94f47743e3c48b5a9894bc9867f8623574d27da6f3dfb3fe3269a384d02c817ef8c81188e559ab173412df79'
            'ea53051356942274ccf6c93928eee24d8b8496c8efcfd3f7035f435d3ce84cccc35bee89a07b2d6a376bf0d4aa4e8ec60ba2592e39463705ffd0f2d77b80a02f'
            '9e8cd963ae01cd86593aab377193ab141f316f9c847cdf375a990a3af27510d69b18bb58bef13fd5c7d7600acbd083aafec462155dd5d7e7c89a20feeb4f4689')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  patch -Np1 -i ${srcdir}/CVE-2025-3155.patch
}

build() {
  cd $pkgname-$pkgver

  export GLIB_COMPILE_SCHEMAS="/usr/bin/glib-compile-schemas"
  ./configure \
    --prefix=/usr \
    --sysconfdir=/etc \
    --localstatedir=/var \
    --disable-static \
    --disable-gtk-doc \
    --enable-compile-warnings=minimum
  sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool

  # documentation generation segfaults without X11
  xvfb-run -a -n 81 -s "-extension GLX -screen 0 1280x1024x24" make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="$pkgdir" install

  # remove unneeded folders from package
  rm -rf "$pkgdir/usr/share/gtk-doc"

  # install license
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}