# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=yajl
pkgver=2.1.0
_debver=$pkgver
_debrel=3
pkgrel=3
pkgdesc="Yet Another JSON Library"
arch=('i686' 'x86_64')
url='https://github.com/lloyd/yajl'
license=('ISC')
makedepends=('cmake' 'doxygen' 'quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/lloyd/yajl/archive/refs/tags/$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/y/yajl/yajl_$_debver-$_debrel.debian.tar.xz")
sha512sums=('9e786d080803df80ec03a9c2f447501e6e8e433a6baf636824bc1d50ecf4f5f80d7dfb1d47958aeb0a30fe459bd0ef033d41bc6a79e1dc6e6b5eade930b19b02'
            '4e9b3751a6aa036524da028d70f1aa57b7bde2d090b039cc091374b668ffca3dbc84ec82e7ce42edfb3eff6d7cb998f3a10b9a3e553267c7a6d46c72135592ed')

prepare() {
  cd "$pkgname-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/multiarch.patch || true

    quilt push -av
  fi
}

build() {
  cmake \
    -S $pkgname-$pkgver \
    -B build \
    -DCMAKE_INSTALL_PREFIX=/usr \
    -Wno-dev
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install
  install -Dm644 "$srcdir/$pkgname-$pkgver/COPYING" -t "$pkgdir/usr/share/licenses/${pkgname}"
}