# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xxhash
pkgver=0.8.0
_debver=0.8.0
_debrel=1
pkgrel=1
pkgdesc='Extremely fast non-cryptographic hash algorithm'
arch=('i686' 'x86_64')
url='https://cyan4973.github.io/xxHash/'
license=('GPL-2' 'Simplified-BSD')
makedepends=('quilt')
source=("$pkgname-$pkgver.tar.gz::https://github.com/Cyan4973/xxHash/archive/v$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xxhash/xxhash_$_debver-$_debrel.debian.tar.xz")
sha512sums=('c3973b3c98bad44e1d8687ab4f9461aecd1c071bb3d320537a4c50fb7301edd13e990bab48cc6e5ca30536a814c8fa8cac24ceb1803a7e8eca30ef73d449373e'
            '48166f498a5cc85c841a8fa097d939e2a3341ffda170468cd3c9fcc08bbcd781a9b899a51f4a2a9a6355e2841db1fada5f695798a3d84f78e1590d503dbf9be8')

prepare() {
  cd "$srcdir/xxHash-$pkgver"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply and seems unimportant
    rm -v debian/patches/reproducible-build.patch || true

    quilt push -av
  fi
}

build() {
  cd "$srcdir/xxHash-$pkgver"
  make PREFIX=/usr
}

package() {
  cd "$srcdir/xxHash-$pkgver"
  make PREFIX=/usr DESTDIR="$pkgdir" install
  install -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 LICENSE "$pkgdir/usr/share/licenses/$pkgname/LICENSE"
}

# vim: ts=2 sw=2 et: