# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xvkbd
pkgver=4.1
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Virtual (graphical) keyboard program for X Window System"
arch=('i686' 'x86_64')
url='http://t-sato.in.coocan.jp/xvkbd/'
license=('GPL-2')
depends=('libxmu' 'libxaw3d' 'libxt' 'libxtst' 'libxp' 'libxpm')
makedepends=('xorg-imake' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/x/xvkbd/xvkbd_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xvkbd/xvkbd_4.1-2.debian.tar.xz"
        "$pkgname.desktop"
        "$pkgname.png")
sha512sums=('6a27a659bacc0f78d70c0afab7ae0f6301f0e7f0c9ed12c581fb4fd5040791536aed50c82ccbd703377244156aade80136567276193f2789a23f05c341b6c0e9'
            '835a0f5ba1d60294d53f02ca7ff16863375cc95a8952895809f699962c085c67c56b1334c7720cf34873d7d746561cd887052cc71d4815d5f0798d33e973b440'
            'a0a9b121c6af26142d790de48863a4b71ea51749d1d23e5919b12f2823e73b271dc1eb52375fe08728b3fce839638b7f4bd0d625df52942146e9a7c0c1dfae5e'
            '506c6812d91528bb76dd47fae28ded6a32c3f8af1329466b5550d8f8d6ea8f7777e4232e0f07d5d37de96a9d152e357176b0718434e9150aa5db67bb6f925540')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/replace-xterm-with-x-terminal-emulator.patch || true

    quilt push -av
  fi
}

build() {
  cd $pkgname-$pkgver
  xmkmf
  sed -i 's|#include <X11/Xaw/|#include <X11/Xaw3d/|' xvkbd.c
  make
}

package() {
  cd $pkgname-$pkgver
  mkdir -p "$pkgdir"/usr/share/X11
  make DESTDIR="$pkgdir" install

  install -Dm644 $srcdir/$pkgname.desktop -t "$pkgdir/usr/share/applications"
  install -Dm644 $srcdir/$pkgname.png -t "$pkgdir/usr/share/pixmaps"

  # fix missing data
  rm -f "$pkgdir"/usr/lib/X11/app-defaults
  mkdir -p "$pkgdir"/usr/lib/X11
  mv "$pkgdir"/etc/X11/app-defaults "$pkgdir"/usr/lib/X11/
  rm -rf "$pkgdir"/etc/

  # license
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}