# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xplc
pkgver=0.3.13
_debver=$pkgver
_debrel=12
pkgrel=2
pkgdesc="Cross-Platform Lightweight Components"
arch=('i686' 'x86_64')
url="http://xplc.sourceforge.net"
license=('LGPL-2.1')
depends=('gcc-libs')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/${pkgname}/$pkgname-$pkgver.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xplc/xplc_$_debver-$_debrel.debian.tar.xz")
sha512sums=('6969ed16c282589ddc285678e1c02016810f83c4c0fea373d8b7a72c97474e6cc21ca3f8f7a7a6aae814037dfae51c3a41bd39f13a67445552b6a7c1b698195d'
            '51f7e115c376e7ebcc7b504bbbe9957d4ce3fee4aa9f905f5f295328ac0dad2cac7d07472ce29fa1d3f7e48d71627441387e2bc510a4cd5cd51c0a31111e11f3')
options=('!buildflags')

prepare() {
  cd "$srcdir/$pkgname-$pkgver"

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/patches ./debian
    rm -rf "$srcdir"/debian

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"

  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --without-libuuid
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  make DESTDIR="$pkgdir" install

  mv "$pkgdir/usr/share/man/man1/"{uuidgen.1,uuidcdef.1}
  rm -f "$pkgdir/usr/bin/uuidgen"

  install -Dm644 LICENSE -t "$pkgdir/usr/share/licenses/$pkgname"
}