# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xournal
pkgver=0.4.8.2016
_debver=$pkgver
_debrel=7
pkgrel=1
pkgdesc="Notetaking and sketching application"
url='http://xournal.sourceforge.net/'
license=('GPL-2')
arch=('i686' 'x86_64')
depends=('libgnomecanvas' 'poppler-glib' 'shared-mime-info' 'desktop-file-utils' 'hicolor-icon-theme')
makedepends=('quilt')
optdepends=('ghostscript: import PS/PDF files as bitmap backgrounds')
source=("https://downloads.sourceforge.net/${pkgname}/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xournal/xournal_0.4.8.2016-7.debian.tar.xz")
sha512sums=('1426d5c9ba3486fbe342d49fc19fcc162965cd6a7b7754f79665e43fe0e60e6f42f61969405ace78fdaa7b99cbb3d4b07b7fb5df246d68a329b52084b6eec76e'
            '16172d53036db0168e13b8c140783baf47c0f6675a778af655884f3e31ba0c356e969115362f380cd26700690b6e07a79d96549602ec306b1f262d43ef39946b')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"
  make DESTDIR="${pkgdir}" install desktop-install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}