# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xmms2
pkgver=0.8
_debver=$pkgver
_debrel=21
pkgrel=5
pkgdesc="X-platform Music Multiplexing System 2"
arch=('i686' 'x86_64')
license=('LGPL-2.1')
install=xmms2.install
_depends=('alsa-lib: ALSA output'
          'boost: C++ bindings'
          'curl: play HTTP streams'
          'python-cython: Python bindings'
          'faad2: AAC support'
          'ffmpeg: WMA, avcodec & avformat support'
          'fftw: visualization'
          'flac: FLAC support'
          'fluidsynth: MIDI support'
          'jack: JACK output'
          'libao: libao output'
          'libcdio-paranoia: CDDA support'
          'libmad: MP3 support'
          'libmms: play MMS streams'
          'libmodplug: MOD support'
          'libmpcdec: Musepack support'
          'libsamplerate: vocoder support'
          'libvorbis: Ogg Vorbis support'
          'libxml2: XSPF and podcast support'
          'mpg123: alternative MP3 support'
          'opusfile: Opus support'
          'perl: Perl bindings'
          'ruby: Ruby bindings'
          'speex: Speex support'
          'wavpack: WavPack support')
makedepends=("${_depends[@]%%:*}" 'waf' 'quilt')
optdepends=("${_depends[@]}")
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/x/xmms2/xmms2_${pkgver}+dfsg.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/x/xmms2/xmms2_${_debver}+dfsg-${_debrel}.debian.tar.xz"
        "fix-build.patch")
sha512sums=('4fb7e2d1e1f07dc2c32320f18da16f03702a61e28e4a6f2144430a18d788e13d0059413ac2f4b39a1a5e81da74cfe33d37d8b43302ee3684e67bdd1f672ef249'
            'f42486173194517f450fa03c673f3bf14afaf603bca365577c2db2a51c1e82716bb78df530ab37bac3a190e44e0c36bba6b246817e21570bec029018bec94d03'
            '0d551c7fa1b273498435e1fe4698c789dceee38ff5cfc03a4e78db432b16d4ee8153a105920d830a580450579d30225e745b4f8defe75b15972c0d264751bf25')

prepare() {
  mv "${pkgname}-${pkgver}+dfsg" "${pkgname}-${pkgver}"
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/bp-Get-rid-of-superfluous-argument-self.patch || true
    rm -v debian/patches/0019-plugins-airplay-build-against-openssl-1.1.0.patch || true

    quilt push -av
  fi

  # additional fixes
  patch -Np1 -i ${srcdir}/fix-build.patch

  sed -i '$a#define AVCODEC_MAX_AUDIO_FRAME_SIZE 192000 /* 1 second of 48kHz 32bit audio */' \
    src/plugins/avcodec/avcodec_compat.h
  sed -i 's,#include <cdio/cdda.h>,#include <cdio/paranoia/cdda.h>,' src/plugins/cdda/cdda.c
  sed -i 's|Werror|Wno-error|g' waftools/*.py
}

build() {
  cd ${pkgname}-${pkgver}
  export LINKFLAGS="$LDFLAGS"
  waf configure --prefix=/usr --without-ldconfig \
    --with-ruby-archdir=`ruby -e 'puts RbConfig::CONFIG["vendorarchdir"]'` \
    --with-ruby-libdir=`ruby -e 'puts RbConfig::CONFIG["vendorlibdir"]'` \
    --with-perl-archdir=`perl -V:installvendorarch | cut -f2 -d\'` \
    --with-optionals=launcher,xmmsclient++,xmmsclient++-glib,perl,ruby,nycli,pixmaps \
    --without-plugins=airplay,apefile,gvfs,pulse,samba \
    --without-optionals=python
  waf build
}

package() {
  cd ${pkgname}-${pkgver}
  waf --destdir="$pkgdir" install

  install -d -o46 -g46 "$pkgdir/var/lib/xmms2"
  install -d -m755 "$pkgdir"/usr/share/licenses/$pkgname
  install -m644 COPYING* "$pkgdir"/usr/share/licenses/$pkgname

  [ -d "$pkgdir"/usr/lib64 ] && \
    { mv "$pkgdir"/usr/lib64/* "$pkgdir"/usr/lib/; rmdir "$pkgdir"/usr/lib64; } || true
}