# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xkeycaps
pkgver=2.47
_debver=2.47
_debrel=7
pkgrel=1
arch=('i686' 'x86_64')
pkgdesc='A graphical front-end to xmodmap'
url='https://www.jwz.org/xkeycaps/'
license=('Expat')
depends=('libxaw')
makedepends=('imake' 'xbitmaps' 'quilt')
source=(https://deb.debian.org/debian/pool/main/x/xkeycaps/xkeycaps_$pkgver.orig.tar.gz
        https://deb.debian.org/debian/pool/main/x/xkeycaps/xkeycaps_$_debver-$_debrel.debian.tar.xz
	license.txt)
sha512sums=('f5f5ecdf83c2bd86eb3d8b8a28b26af25a2dc9ff0a9c44091d8eb154d617b4373191a2e4479bb0e3025c023d6e5d785a088c64bc269c1c43431a3d2fc91c1a7e'
            '85d72cbd4012299ab60ab700049862c1ab514c904acb8e3810fd7886cacb0712c3849fbc52dee499007d97ce8aa301a34d901120a46ba15a32151986121fbbbc'
            'dc07c0ff12bb103bcb42911977849c586364ba39cf171d3761c37e69131a933545d6b149b1ced8ff9fd9dd0dfc81bad9ac39e26c22c867fca38f85ccdff74220')

prepare() {
  cd "$srcdir"/$pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir"/$pkgname-$pkgver
  xmkmf
  make MANPATH=/usr/share/man
}

package() {
  cd "$srcdir"/$pkgname-$pkgver
  make DESTDIR="$pkgdir" install
  make DESTDIR="$pkgdir" MANPATH=/usr/share/man install.man
  install -Dm644 ../license.txt \
    "$pkgdir"/usr/share/licenses/$pkgname/license.txt
}