# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xkeyboard-config
pkgver=2.29
_debver=2.29
_debrel=2
pkgrel=2
pkgdesc="X keyboard configuration files"
arch=(any)
license=('X11')
url="https://www.freedesktop.org/wiki/Software/XKeyboardConfig"
makedepends=('intltool' 'xenocara-xkbcomp' 'libxslt' 'python' 'quilt')
provides=('xkbdata')
replaces=('xkbdata')
conflicts=('xkbdata')
source=(https://xorg.freedesktop.org/archive/individual/data/$pkgname/$pkgname-$pkgver.tar.bz2
        https://deb.debian.org/debian/pool/main/x/xkeyboard-config/xkeyboard-config_$_debver-$_debrel.diff.gz
        revert-fullscreen.patch)
sha512sums=('202255af097f3063d76341d1b4a7672662dc645f9bcd7afa87bc966a41db4c20fc6b8f4fbe2fcaec99b6bc458eac10129141a866a165857c46282f6705b78670'
            '9107dd2fb57cc04457a182fae1f9def0eaf67111be4972bccf505307afdef9d23b887195368dcb43a612fdc5c56795322b96b6f9044a994e6dd2e86aefb1fb16'
            '09f8bd832512c59da11fbddd709018422680c2c5eecc38a33f37e55cf3d7f5a2b5dfbf4d5e26fb862957ba52253637f0700e301c2880938cf8b1f119e53153aa')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    patch -p1 -i "$srcdir"/xkeyboard-config_$_debver-$_debrel.diff

    quilt push -av
  fi
  # fix FS#1576 https://issues.hyperbola.info/index.php?do=details&task_id=1576
  patch -p1 -i "$srcdir/revert-fullscreen.patch"
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr \
      --with-xkb-base=/usr/share/X11/xkb \
      --with-xkb-rules-symlink=xorg \
      --enable-compat-rules=yes
  make
}

package() {
  cd $pkgname-$pkgver

  make DESTDIR="$pkgdir" install
  rm -f "$pkgdir/usr/share/X11/xkb/compiled"

  install -m755 -d "$pkgdir/var/lib/xkb"
  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}