# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xine-ui
pkgver=0.99.9
_debver=$pkgver
_debrel=2
pkgrel=5
pkgdesc="A free and libre video player"
arch=('i686' 'x86_64')
license=('GPL-2')
url='https://www.xine-project.org'
depends=('xine-lib' 'curl' 'libxft' 'libxxf86vm' 'xdg-utils')
makedepends=('quilt')
source=("https://downloads.sourceforge.net/xine/${pkgname}-${pkgver}.tar.xz"
        "https://deb.debian.org/debian/pool/main/x/xine-ui/xine-ui_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('575b20a19c5740ba0336af9dea0a1bc15d23b7471379b9d72aeb585e23f95b336368b96a28d4804726507f059dc431cc3f9adfd8b615b08c0e67b65287c2b6c7'
            '820fae581ef80a23a64f9fc27864ea3a2a8ec3585cf11493e767cc047686101f91c9bcb2099c79fecc6f6a766a3ecbfc6385b4914a6903fe9233582732340df8')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr \
    --mandir=/usr/share/man \
    --with-x \
    --disable-lirc \
    --without-aalib \
    --disable-debug
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" desktopdir=/usr/share/applications install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}