# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xfig
pkgver=3.2.8b
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="An interactive, free and libre drawing tool"
arch=('i686' 'x86_64')
url='https://mcj.sourceforge.net/'
license=('Expat')
depends=('libjpeg-turbo' 'libxaw3d' 'xenocara-fonts-misc-meta' 'xenocara-font-bitstream-75dpi'
         'xenocara-font-bitstream-100dpi' 'libpng' 'libxpm' 'ghostscript')
makedepends=('fig2dev' 'libxaw' 'quilt')
optdepends=('fig2dev: to use the frontend to convert fig files')
options=('!makeflags' '!emptydirs')
source=("${pkgname}-${pkgver}.tar.xz::https://deb.debian.org/debian/pool/main/x/xfig/xfig_${pkgver}.orig.tar.xz"
        "https://deb.debian.org/debian/pool/main/x/xfig/xfig_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('5cc5e61977f97956baca77bf4bce09d0f47ea6fafb10055d0523f7cccd72d7af80e706daa62ae16df3fc54338b4f6cd4a6b71dc460311e65be749ec84fa662b3'
            '1b57d2ab5c40b880abe2326998c869cf4d519075c6c1285ce0537233545741dd9ad0e1c805e3f79852dd47677ebdc91040318599c0de6083d810fc27a031aff4')

prepare() {
  cd ${pkgname}-${pkgver}
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
  autoreconf
}

build() {
  cd ${pkgname}-${pkgver}
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd ${pkgname}-${pkgver}
  make DESTDIR="${pkgdir}" install
  install -Dm644 debian/copyright -t "${pkgdir}/usr/share/licenses/${pkgname}"
}