# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xwud package

pkgname=xenocara-xwud
_openbsdver=6.9
pkgver=1.0.5
pkgrel=3
pkgdesc="X Window System image undumping utility, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xwud')
conflicts=('xorg-xwud')
replaces=('xorg-xwud')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xwud-$pkgver.tar.lz{,.sig})
sha512sums=('f56ca5fba3791685086f906b96e84a247d69586db19cf42bc3309a02faac6a6221e72c689e1d8c111755b0eafa9c998ad280b6688813d0b295e3800ff0fb0524'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xwud"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xwud"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xwud"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}