# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xwininfo package

pkgname=xenocara-xwininfo
_openbsdver=6.9
pkgver=1.1.5
pkgrel=2
pkgdesc="Command-line utility to print information about windows on an X server, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libxcb')
makedepends=('xenocara-util-macros' 'libx11' 'gettext-tiny')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xwininfo')
conflicts=('xorg-xwininfo')
replaces=('xorg-xwininfo')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xwininfo-$pkgver.tar.lz{,.sig})
sha512sums=('f8c774d9f764e955d832137caaa28bf733bab6e2410b359c071dd148411145c0b8260c827aef1f2aea8b364c0e3fca01ef87d2eca96d3be67254437768d0ad2f'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xwininfo"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xwininfo"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xwininfo"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}