# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xvinfo package

pkgname=xenocara-xvinfo
_openbsdver=6.9
pkgver=1.1.3
pkgrel=3
pkgdesc="Prints out the capabilities of any video adaptors associated with the display that are accessible through the X-Video extension, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxv')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xvinfo')
conflicts=('xorg-xvinfo')
replaces=('xorg-xvinfo')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xvinfo-$pkgver.tar.lz{,.sig})
sha512sums=('f63c087a36fdc83d917475ca51238b779b7ec5f66261b62886046378c0a3040d6c9a84fd2a956064ae37a8170819faff9a2a47e50eea665f1873b2d060afc8ba'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xvinfo"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xvinfo"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xvinfo"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}