# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xset package

pkgname=xenocara-xset
_openbsdver=6.9
pkgver=1.2.4
pkgrel=3
pkgdesc="User preference utility for X, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxmu')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xset')
conflicts=('xorg-xset')
replaces=('xorg-xset')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xset-$pkgver.tar.lz{,.sig})
sha512sums=('59ab1a9a68c6076247a694b3c8e024e161b935d6d6859c86c3efe8bd897a1c874eee320a171b39dad5188e2baf5da6d3a23688259c89f06b78aa57574e702263'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xset"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xset"
  ./configure --prefix=/usr --without-fontcache --without-xf86misc
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xset"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}