# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xrandr package

pkgname=xenocara-xrandr
_openbsdver=6.9
pkgver=1.5.1
pkgrel=2
pkgdesc="Primitive command line interface to RandR extension, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('Expat')
depends=('libxrandr' 'libx11')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xrandr')
conflicts=('xorg-xrandr')
replaces=('xorg-xrandr')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xrandr-$pkgver.tar.lz{,.sig})
sha512sums=('fbe72f8faedc0b78d182cc4442ae50c1f67f530b9dc651055d63e0bbfc7ce36e2251a0a61521452ac7f24d734b995c84914d7f2c1693189f770852c3f264ef41'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xrandr"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xrandr"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xrandr"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
  rm -f "$pkgdir/usr/bin/xkeystone"
}