# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xmodmap package

pkgname=xenocara-xmodmap
_openbsdver=6.9
pkgver=1.0.10
pkgrel=2
pkgdesc="Utility for modifying keymaps and button mappings, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xmodmap')
conflicts=('xorg-xmodmap')
replaces=('xorg-xmodmap')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xmodmap-$pkgver.tar.lz{,.sig})
sha512sums=('cf98fd6a12e7190d169e926bc0350d70687890cf9be6e78b228fb5ede42d33c820a5631be57a6190f1dacdfc112408cbae0b84588a9b839b1bf6de973d491211'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xmodmap"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xmodmap"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xmodmap"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}