# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xmessage package

pkgname=xenocara-xmessage
_openbsdver=6.9
pkgver=1.0.5
pkgrel=3
pkgdesc="Display a message or query in a window, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxaw')
makedepends=('xenocara-util-macros')
provides=('xorg-xmessage')
conflicts=('xorg-xmessage')
replaces=('xorg-xmessage')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xmessage-$pkgver.tar.lz{,.sig})
sha512sums=('ae057fe470a9faa1155357fee4c986c4615099380524c51bb5f749a772dedb3eca8f68a4386772eacc8bcca5643293b69f0d8ac03dc86c471ff4f6754efd9ba1'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xmessage"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xmessage"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xmessage"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}