# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xlsfonts package

pkgname=xenocara-xlsfonts
_openbsdver=6.9
pkgver=1.0.6
pkgrel=1
pkgdesc="List available X fonts, provided by Xenocara"
url='https://www.xenocara.org'
license=('X11')
arch=('i686' 'x86_64')
depends=('libx11')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xlsfonts')
conflicts=('xorg-xlsfonts')
replaces=('xorg-xlsfonts')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xlsfonts-$pkgver.tar.lz{,.sig})
sha512sums=('e952b942ab2e7e5bbc576400056b6c3cb0eb8b4967f88da0dd13fd262e6c108cb0362659a1481cb9050517928dafe727bb307a4add508e15be1959aaf5b09ed8'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xlsfonts"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xlsfonts"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xlsfonts"
  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/${pkgname}"
}