# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xlsatoms package

pkgname=xenocara-xlsatoms
_openbsdver=6.9
pkgver=1.1.3
pkgrel=2
pkgdesc="List interned atoms defined on server, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libxcb')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xlsatoms')
conflicts=('xorg-xlsatoms')
replaces=('xorg-xlsatoms')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xlsatoms-$pkgver.tar.lz{,.sig})
sha512sums=('b6633cd673f9ca144f0963015f67d621a6d72f5fbd328645867e6c8f9ad14a35403561430f7714ba421a2c3dcac1db6921399380053364ab825c2d83b9282b02'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xlsatoms"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xlsatoms"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xlsatoms"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}