# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xkill package

pkgname=xenocara-xkill
_openbsdver=6.9
pkgver=1.0.5
pkgrel=3
pkgdesc="Kill a client by its X resource, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxmu')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xkill')
conflicts=('xorg-xkill')
replaces=('xorg-xkill')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xkill-$pkgver.tar.lz{,.sig})
sha512sums=('95e81a92a0e087f7bed596b61ce68319d342d622cbdd99026e63c2a8a86326d3dfc3d070a895837361e1946a69a932de3d99a864401f3b0000bfda98bff07eb9'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xkill"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xkill"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xkill"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}