# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xhost package

pkgname=xenocara-xhost
_openbsdver=6.9
pkgver=1.0.8
pkgrel=2
pkgdesc="Server access control program for X, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxmu')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xhost')
conflicts=('xorg-xhost')
replaces=('xorg-xhost')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xhost-$pkgver.tar.lz{,.sig}
        fix-missing-netdb-include-file.patch)
sha512sums=('4677d43fa8857bd56841328ecff420f294f90e467944551f2306a040ec83edcae4d6e847dd5bb9915a3fc249ea1f7ca5ddd917162ad15dc3b342c7c88f274425'
            'SKIP'
            'ab344b1b3c88f5742e4da05e6eb584d1c8bdae1fdffb6ad02e9f904e43bb893ca3434caeedd5112aabb55709b336655ca79ea849edc0218d1dfd67d524b2ba5a')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xhost"
  patch -p1 -i "$srcdir/fix-missing-netdb-include-file.patch"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xhost"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xhost"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}