# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xgamma package

pkgname=xenocara-xgamma
_openbsdver=6.9
pkgver=1.0.6
pkgrel=3
pkgdesc="Alter a monitor's gamma correction, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxxf86vm')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xgamma')
conflicts=('xorg-xgamma')
replaces=('xorg-xgamma')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xgamma-$pkgver.tar.lz{,.sig})
sha512sums=('c339ad4f63bb5be2c823c49377646a0658b02871086541b4561a78d3f93ed34e57619964988be8da7d49b740c95460fbdf6415383b91a903d145a13102faf2ef'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xgamma"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xgamma"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xgamma"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}