# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xdpyinfo package

pkgname=xenocara-xdpyinfo
_openbsdver=6.9
_pkgname=xdpyinfo
pkgver=1.3.2
pkgrel=4
pkgdesc="Display information utility for X, provided by Xenocara"
arch=('i686' 'x86_64')
url='https://www.xenocara.org'
license=('Expat')
depends=('libx11' 'libxext' 'libxtst' 'libxxf86vm' 'libxrender' 'libxcomposite' 'libxinerama')
makedepends=('xenocara-util-macros' 'xorgproto')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xdpyinfo')
conflicts=('xorg-xdpyinfo')
replaces=('xorg-xdpyinfo')
source=("https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/$_pkgname-$pkgver.tar.lz"{,.sig})
sha512sums=('731e74627b70731f2b0a204c16bc18dda54f4ad8f8bffbc6e175ca7d8ca12ff2f9487c2d5269171bab317a546d66d955278ebcfb93451a9a627e6ac0f0e2f289'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/$_pkgname"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/$_pkgname"
  ./configure --prefix=/usr --sysconfdir=/etc
  make
}

package() {
  cd "xenocara-$_openbsdver/app/$_pkgname"
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname"
}