# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xclock package

pkgname=xenocara-xclock
_openbsdver=6.9
pkgver=1.0.9
pkgrel=2
pkgdesc="X clock, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libx11' 'libxmu' 'libxaw' 'libxrender' 'libxft' 'libxkbfile')
makedepends=('xenocara-util-macros' 'gettext-tiny')
provides=('xorg-xclock')
conflicts=('xorg-xclock')
replaces=('xorg-xclock')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xclock-$pkgver.tar.lz{,.sig})
sha512sums=('f22811d78929fbd7ad73e60594bc6a6676869b931c2303ed10a5fe467ed326ba33686f44b8ee7343f4e000b4231237a715c45df032a4be66a6adc0b6de6d5c5c'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xclock"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xclock"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xclock"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}