# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xbiff package

pkgname=xenocara-xbiff
_openbsdver=6.9
pkgver=1.0.4
pkgrel=2
pkgdesc="Watch mailboxes for new message delivery, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('X11')
depends=('libxaw' 'libxext')
makedepends=('xenocara-util-macros' 'xenocara-xbitmaps')
provides=('xorg-xbiff')
conflicts=('xorg-xbiff')
replaces=('xorg-xbiff')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xbiff-$pkgver.tar.lz{,.sig})
sha512sums=('72f006be41293ddbd302379f9a935b11e0d8eaf82a164fdffc7392312904f13a2962ab2df2acbc52002e8804b5c92612f3ba7955cf87839c06976bf3f1355f3c'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xbiff"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xbiff"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xbiff"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}