# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xbacklight package

pkgname=xenocara-xbacklight
_openbsdver=6.9
pkgver=1.2.3
pkgrel=2
pkgdesc="RandR-based backlight control application, provided by Xenocara"
arch=('i686' 'x86_64')
url="https://www.xenocara.org"
license=('Expat')
depends=('xcb-util')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xbacklight')
conflicts=('xorg-xbacklight')
replaces=('xorg-xbacklight')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xbacklight-$pkgver.tar.lz{,.sig})
sha512sums=('b97bef98ad196f5c0e7f984eb39c6424f2e967319a8d500a8a2bc62af45b8fe69c713166ce538feb19922a650f7957a5331613b56c46fef946537c87caba961a'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xbacklight"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xbacklight"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xbacklight"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}