# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-xauth package

pkgname=xenocara-xauth
_openbsdver=6.9
pkgver=1.1
pkgrel=2
pkgdesc="Xenocara authorization settings program"
arch=(i686 x86_64)
license=('X11')
url="https://www.xenocara.org"
depends=('libxmu' 'libxtrans')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-xauth')
conflicts=('xorg-xauth')
replaces=('xorg-xauth')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/xauth-$pkgver.tar.lz{,.sig})
sha512sums=('30a39cb4125a44bce840e11c320a76dfb6714075484e579637513f3c503fc243e1e3503b96584ba5d8b7c7c83dead164154232c633cecb9a3a15c4306335b1b4'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/xauth"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/xauth"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/xauth"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}