# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xf86-video-vesa package

pkgname=xenocara-video-vesa
_openbsdver=6.9
pkgver=2.3.4
pkgrel=6
pkgdesc="Xenocara vesa video driver"
arch=(i686 x86_64)
license=('X11')
url="https://www.xenocara.org"
depends=('glibc')
makedepends=('xenocara-server-devel' 'X-ABI-VIDEODRV_VERSION=24.0' 'xenocara-util-macros')
provides=('xf86-video-vesa')
conflicts=('xf86-video-vesa' 'xenocara-server<1.20' 'X-ABI-VIDEODRV_VERSION<24' 'X-ABI-VIDEODRV_VERSION>=25')
replaces=('xf86-video-vesa')
groups=('xenocara-video-drivers' 'xenocara-video' 'xenocara-drivers'
        'xorg-video-drivers' 'xorg-video' 'xorg-drivers')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/driver/xf86-video-vesa-$pkgver.tar.lz{,.sig}
        revert-kernelcheck.patch)
sha512sums=('d80ae6384e06876d0b462263591332ed8e5f926ca9a14cf4b34fc9ecbd6da7761d2bafe10377c1017daf3c24fd3c53dd1521e3ceb3fdc75ec16316c857f9798b'
            'SKIP'
            '2357f9b30732321c774073c3e233d16ebff29aab31bcebf7c6481bd2187554e85ec8b9cd375eaa836b433dfaba4d9e9cea1dcf3659803a388ceb6699ed905923')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/driver/xf86-video-vesa"
  patch -p1 -R -i "$srcdir/revert-kernelcheck.patch"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/driver/xf86-video-vesa"

  # Since pacman 5.0.2-2, hardened flags are now enabled in makepkg.conf
  # With them, module fail to load with undefined symbol.
  # See https://bugs.archlinux.org/task/55102 / https://bugs.archlinux.org/task/54845
  export CFLAGS=${CFLAGS/-fno-plt}
  export CXXFLAGS=${CXXFLAGS/-fno-plt}
  export LDFLAGS=${LDFLAGS/,-z,now}

  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/driver/xf86-video-vesa"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}