# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-smproxy package

pkgname=xenocara-smproxy
_openbsdver=6.9
pkgver=1.0.6
pkgrel=3
pkgdesc="Allows X applications that do not support X11R6 session management to participate in an X11R6 session, provided by Xenocara"
arch=(i686 x86_64)
url="https://www.xenocara.org"
license=('X11')
depends=('libsm' 'libxt' 'libxmu')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
provides=('xorg-smproxy')
conflicts=('xorg-smproxy')
replaces=('xorg-smproxy')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/smproxy-$pkgver.tar.lz{,.sig})
sha512sums=('a63fede2820708c90535760ee897706dac08936e272a1f1779ba995f3939d3c6abab9ca74bbf4dc851790a7fb9ef800213f18f6bf98bbceeadfb57793ada9df9'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/app/smproxy"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/smproxy"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/smproxy"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}