# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorgproto package

pkgname=xenocara-proto
_openbsdver=6.9
pkgver=2019.2
pkgrel=2
pkgdesc="combined Xenocara X11 Protocol headers"
arch=('any')
url="https://www.xenocara.org"
license=('X11')
makedepends=('xenocara-util-macros')
provides=('xorgproto' 'bigreqsproto' 'compositeproto' 'damageproto' 'dmxproto' 'dri2proto' 'dri3proto' 'fixesproto' 'fontsproto' 'glproto' 'inputproto' 'kbproto' 'presentproto' 'printproto' 'randrproto' 'recordproto' 'renderproto' 'resourceproto' 'scrnsaverproto' 'videoproto' 'xcmiscproto' 'xextproto' 'xf86dgaproto' 'xf86driproto' 'xf86miscproto' 'xf86vidmodeproto' 'xineramaproto' 'xproto')
conflicts=('xorgproto' 'bigreqsproto' 'compositeproto' 'damageproto' 'dmxproto' 'dri2proto' 'dri3proto' 'fixesproto' 'fontsproto' 'glproto' 'inputproto' 'kbproto' 'presentproto' 'printproto' 'randrproto' 'recordproto' 'renderproto' 'resourceproto' 'scrnsaverproto' 'videoproto' 'xcmiscproto' 'xextproto' 'xf86dgaproto' 'xf86driproto' 'xf86miscproto' 'xf86vidmodeproto' 'xineramaproto' 'xproto')
replaces=('xorgproto' 'bigreqsproto' 'compositeproto' 'damageproto' 'dmxproto' 'dri2proto' 'dri3proto' 'fixesproto' 'fontsproto' 'glproto' 'inputproto' 'kbproto' 'presentproto' 'printproto' 'randrproto' 'recordproto' 'renderproto' 'resourceproto' 'scrnsaverproto' 'videoproto' 'xcmiscproto' 'xextproto' 'xf86dgaproto' 'xf86driproto' 'xf86miscproto' 'xf86vidmodeproto' 'xineramaproto' 'xproto')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/proto/xorgproto-$pkgver.tar.lz{,.sig})
sha512sums=('9c2460355559294e251c63f3725d5408a4a2e9a1069d2d17f02dc77b5de30c4fab5546a64e1e2ae34389bf7215bf7ad39c949191a73d93c4383853602b82f595'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/proto/xorgproto"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/proto/xorgproto"
  # do not try to build additional docs, we don't have xenocara-sgml-doctools
  ./configure --prefix=/usr \
    --without-xmlto \
    --without-xsltproc \
    --without-fop
  make
}

check() {
  cd "xenocara-$_openbsdver/proto/xorgproto"
  make -k check
}

package() {
  cd "xenocara-$_openbsdver/proto/xorgproto"
  make DESTDIR="$pkgdir/" install

  # licenses
  install -m755 -d "$pkgdir/usr/share/licenses/$pkgname"
  install -m644 COPYING* "$pkgdir/usr/share/licenses/$pkgname/"

  # cleanup
  rm -f $pkgdir/usr/include/X11/extensions/{apple,windows}*
  rm -f $pkgdir/usr/share/licenses/$pkgname/COPYING-{apple,windows}wmproto
  rm -f $pkgdir/usr/share/pkgconfig/{apple,windows}wmproto.pc
}