# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-font-util package

pkgname=xenocara-font-util
_openbsdver=6.9
pkgver=1.3.2
pkgrel=2
pkgdesc='Xenocara font utilities'
url="https://www.xenocara.org"
arch=('i686' 'x86_64')
license=('X11')
makedepends=('xenocara-util-macros')
groups=('xenocara-fonts' 'xenocara' 'xorg-fonts' 'xorg')
provides=('font-util' 'xorg-font-util')
conflicts=('font-util' 'xorg-font-util')
replaces=('font-util' 'xorg-font-util')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/font/util-$pkgver.tar.lz{,.sig})
sha512sums=('38a73e9f09e01773bb98fbb01c3ff4df43e0444319621d718ba3a6d3c2abd1e3bf1849fb5e95ad51945a231964e18be41ecb76a71e09712ac45a182f2def8845'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/font/util"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/font/util"
  ./configure --prefix=/usr \
      --mandir=/usr/share/man \
      --with-mapdir=/usr/share/fonts/util \
      --with-fontrootdir=/usr/share/fonts
  make
}

package() {
  cd "xenocara-$_openbsdver/font/util"
  make DESTDIR="$pkgdir/" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"
}