# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-fonts-encodings package

pkgname=xenocara-font-encodings
_openbsdver=6.9
pkgver=1.0.5
pkgrel=3
pkgdesc="Xenocara font encoding files"
arch=('any')
url='https://www.xenocara.org'
license=('Public-Domain')
makedepends=('xenocara-mkfontscale' 'xenocara-util-macros' 'xenocara-font-util')
groups=('xenocara-fonts' 'xenocara' 'xorg-fonts' 'xorg')
provides=('xorg-fonts-encodings')
conflicts=('xorg-fonts-encodings')
replaces=('xorg-fonts-encodings')
options=(!makeflags)
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/font/encodings-$pkgver.tar.lz{,.sig})
sha512sums=('79a1b7477a94db01c75bdc49a00fcf5dd19ae38e7881621048f7a1ff85725aa0053adda570189da467e2a1f46f2835ec3cd772e23e4e6c175a0e5bb845f28bd4'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

prepare() {
  cd "xenocara-$_openbsdver/font/encodings"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/font/encodings"
  ./configure --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/font/encodings"
  make DESTDIR="$pkgdir" install

  install -Dm644 COPYING "$pkgdir/usr/share/licenses/$pkgname/COPYING"

  # regenerate encodings file not to include non-compressed versions
  cd "$pkgdir/usr/share/fonts/encodings/large"
  mkfontscale -b -s -l -n -r -p /usr/share/fonts/encodings/large -e . .
  cd "$pkgdir/usr/share/fonts/encodings"
  mkfontscale -b -s -l -n -r -p /usr/share/fonts/encodings -e . -e large .
}