# Maintainer: Jesus E. <heckyel@riseup.net>

# Based on xorg-editres package

pkgname=xenocara-editres
_openbsdver=6.9
pkgver=1.0.7
pkgrel=2
pkgdesc="A dynamic resource editor for X Toolkit applications, provided by Xenocara"
url='https://www.xenocara.org'
arch=('i686' 'x86_64')
license=('Expat')
depends=('libxt' 'libxaw')
makedepends=('xenocara-util-macros')
groups=('xenocara-apps' 'xenocara' 'xorg-apps' 'xorg')
source=(https://repo.hyperbola.info:50000/sources/xenocara-libre/$_openbsdver/app/editres-$pkgver.tar.lz{,.sig})
sha512sums=('2fbdd8b341aac6d4d8a21f2a55be2fc025d87ad72b504967011029aa0ea770e4f2267173d662b9675fc6e9c6faa86d4c9d73caaa70026902c1a8aa8eed3904b7'
            'SKIP')
validpgpkeys=('C92BAA713B8D53D3CAE63FC9E6974752F9704456') # André Silva

CFLAGS=${CFLAGS/-Werror=format-security/}

prepare() {
  cd "xenocara-$_openbsdver/app/editres"
  autoreconf -vfi
}

build() {
  cd "xenocara-$_openbsdver/app/editres"
  ./configure \
    --prefix=/usr
  make
}

package() {
  cd "xenocara-$_openbsdver/app/editres"
  make DESTDIR="$pkgdir" install
  install -Dm644 COPYING -t "$pkgdir/usr/share/licenses/$pkgname/"
}