# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xdg-utils
pkgver=1.1.3
_debver=$pkgver
_debrel=4.1
pkgrel=3
pkgdesc="Command line tools that assist applications with a variety of desktop integration tasks"
arch=('any')
url="https://www.freedesktop.org/wiki/Software/xdg-utils/"
license=('Expat')
depends=('sh' 'xenocara-xset')
makedepends=('docbook-xsl' 'lynx' 'xmlto' 'git-legacy' 'quilt')
optdepends=('xenocara-xprop: for Xfce support in xdg-open'
            'perl-file-mimeinfo: for generic support in xdg-open'
            'perl-x11-protocol: Perl X11 protocol support')
source=(https://portland.freedesktop.org/download/$pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/x/xdg-utils/xdg-utils_$_debver-$_debrel.debian.tar.xz
        libre.patch)
sha512sums=('d1f819a211eb4104a90dfdc6fedcb640fd46b15ccfc8762266f8f538c49d74cb00027b8c1af991fb2a200acb4379986ae375700e06a2aa08fb41a38f883acb3e'
            '31c30c802b41eaaa67909af309d16469acb2f3793b28b7a6867a63b1e9433fa052677ee7fa0d9eb50f6f7397c6dc692dd23bdadbe2bfce89e8b9f51466f3de6f'
            '73392f2eb53b79a6c6969d9c4c5d7f3f70e5998effa429a77f3d4cd385146f2f99d5fd0251b015cd1374b7c4623891eb4e99a25ad9025ab7ca9b3661ccfd1f32')

prepare() {
  cd $pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi


  # add Iceape-UXP, Iceweasel-UXP and Midori support
  patch -Np1 -i $srcdir/libre.patch
}

build() {
  cd $pkgname-$pkgver
  ./configure --prefix=/usr --mandir=/usr/share/man
  make
}

package() {
  cd $pkgname-$pkgver
  make DESTDIR="${pkgdir}" install
  install -D -m644 LICENSE "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"

  # install empty directory to prevent xdg-desktop-menu install *.desktop to fail, see FS#33316
  install -dm755 $pkgdir/usr/share/desktop-directories
}