# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=xbanish
pkgver=1.7
_debver=$pkgver
_debrel=2
pkgrel=1
pkgdesc="Hide the mouse cursor when typing"
url='https://github.com/jcs/xbanish'
arch=('i686' 'x86_64')
license=('Modified-BSD')
depends=('libxfixes' 'libxi')
makedepends=('libxt' 'quilt')
source=("${pkgname}-${pkgver}.tar.gz::https://deb.debian.org/debian/pool/main/x/xbanish/xbanish_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/x/xbanish/xbanish_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('f790ea888812bb6b7793f0a60a900724fc407ec4485672e37d464387ffacfa4bf2dc891862f3fed06948cda31024745816b3adb58074c4578edc6a9848f2bd08'
            '53fb3d24b967fcff635ae615ef93af8ca79aa7d45299f2d9979a0b670b41b6cc529cd7c5fd3cd276b18fca394dece7d1b379ea5df00168e0df9ec00cca1536c6')

prepare() {
  cd $pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cd "$srcdir/$pkgname-$pkgver"
  make
}

package() {
  cd "$srcdir/$pkgname-$pkgver"
  install -Dm755 xbanish "$pkgdir/usr/bin/xbanish"
  install -Dm644 xbanish.1 "$pkgdir/usr/share/man/man1/xbanish.1"
  install -Dm644 README.md "$pkgdir/usr/share/doc/$pkgname/README.md"
  install -Dm644 debian/copyright -t "$pkgdir/usr/share/licenses/$pkgname"
}