# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=x11-ssh-askpass
pkgver=1.2.4.1
_debver=1.2.4.1
_debrel=10
pkgrel=6
pkgdesc='Lightweight passphrase dialog for SSH'
url='http://www.jmknoble.net/software/x11-ssh-askpass/'
license=('Expat')
arch=('i686' 'x86_64')
depends=('libxt')
makedepends=('xorg-imake' 'quilt')
source=("https://deb.debian.org/debian/pool/main/s/ssh-askpass/ssh-askpass_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/s/ssh-askpass/ssh-askpass_$_debver-$_debrel.debian.tar.xz")
sha512sums=('879887cc1d6eb26662494e3a6b59b79a8d153b354abf86e8e8667940545c8e07d0aa051491f5ba6ca5273e3a7fcc367edb4cc79bb2e4bf1bdbd0e234690ad6b9'
            '888dd5fd096f9524f2dc75cc4f00f4e4ed931f446245ffff02225608d36cac7d6c3a8307a5274e73f798844c02cddec718cab4af39e5b9097d2227af3f43d11b')
install=${pkgname}.install

prepare() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
		# Debian patches
		export QUILT_PATCHES=debian/patches
		export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
		export QUILT_DIFF_ARGS='--no-timestamps'

		mv "$srcdir"/debian .

		quilt push -av
	fi
}

build() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	./configure \
		--mandir=/usr/share/man \
		--libexecdir=/usr/libexec/ssh \
		--with-app-defaults-dir=/usr/share/X11/app-defaults \

	xmkmf
	make includes
	make
}

package() {
	cd "${srcdir}/${pkgname}-${pkgver}"
	make DESTDIR="${pkgdir}" install install.man
	install -d "${pkgdir}/usr/share/licenses/${pkgname}"
	sed '109,174p;d' README > "${pkgdir}/usr/share/licenses/${pkgname}/LICENSE"
}