# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=vym
pkgver=2.6.11
_debver=$pkgver
_debrel=3
pkgrel=1
pkgdesc="A free and libre mindmapping tool"
arch=('i686' 'x86_64')
url='http://www.insilmaril.de/vym/'
license=('GPL-2')
depends=('qt-svg' 'desktop-file-utils' 'zip' 'unzip')
makedepends=('qt-tools' 'quilt')
source=("https://downloads.sourceforge.net/sourceforge/${pkgname}/${pkgname}-${pkgver}.tar.bz2"
        "https://deb.debian.org/debian/pool/main/v/vym/vym_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('d6ae8346152ab10e12a68f25b4c13c4d40e1a8471df348ba0df9c05bdbe60f86a97912fcca268ec510246fe655a7dcc2d2e9a9332daee09a2a7dda7d6f880aa1'
            '23654981380768d9d76371fb42e56974b44e1c6cf6e00f15dc3fbfa6e717db62bda93cab6fe193cd672446a15834232a7140cc3e9022441675119511a1ceeb86')

prepare() {
  cd "${srcdir}"/$pkgname-$pkgver
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi

  cd lang
  lrelease *.ts
}

build() {
  cd "${srcdir}"/$pkgname-$pkgver

  qmake PREFIX=/usr/share NO_DBUS=yes
  make
}

package() {
  cd "${srcdir}"/$pkgname-$pkgver

  # install files
  make INSTALL_ROOT="${pkgdir}" install

  # fix executable path
  mv "${pkgdir}"/usr/share/bin "${pkgdir}"/usr/bin

  # install documentation
  install -Dm644 "${srcdir}"/$pkgname-$pkgver/doc/$pkgname.1.gz "${pkgdir}"/usr/share/man/man1/$pkgname.1.gz
  install -Dm644 "${srcdir}"/$pkgname-$pkgver/doc/$pkgname.pdf "${pkgdir}"/usr/share/doc/$pkgname/$pkgname.pdf
  rm -rf "${pkgdir}"/usr/share/doc/packages

  # .desktop and icon file
  install -Dm644 debian/$pkgname.desktop -t "${pkgdir}"/usr/share/applications
  install -Dm644 "${pkgdir}"/usr/share/vym/icons/$pkgname.png "${pkgdir}"/usr/share/pixmaps/$pkgname.png

  # license
  install -Dm644 LICENSE.txt -t "${pkgdir}"/usr/share/licenses/$pkgname
}