# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=vorbis-tools
pkgver=1.4.0
_debver=1.4.0
_debrel=11
pkgrel=1
pkgdesc='Extra tools for Ogg-Vorbis'
arch=('i686' 'x86_64')
url='https://www.xiph.org/vorbis/'
license=('GPL-2')
depends=('libao' 'libvorbis' 'curl' 'flac')
makedepends=('quilt')
source=("https://downloads.xiph.org/releases/vorbis/${pkgname}-${pkgver}.tar.gz"
        "https://deb.debian.org/debian/pool/main/v/vorbis-tools/vorbis-tools_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('d2473f2e8e6726b5a5083f567797ae42bbb7fa3f26aec3f7b83e641e028c64726299f71a9d75258595a53cf29c18acb84841bcbc39509258d2c8df859e4e3b99'
            '78f596427db29608c9529d7651241112d797ab54cab4f86dccf57d419adfddf0c448b564aaf2f00da62425e02a5aa94031c6c0926a42f837463655530ff60a34')

prepare() {
  cd ${pkgname}-${pkgver}

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian/patches ./debian
    rm -rf "$srcdir"/debian/

    quilt push -av
  fi
}

build() {
  cd ${pkgname}-${pkgver}

  ./configure \
    --prefix=/usr \
    --without-speex \
    --enable-vcut
  make
}

package() {
  cd ${pkgname}-${pkgver}

  make DESTDIR="${pkgdir}" install
  install -Dm644 COPYING -t "${pkgdir}/usr/share/licenses/$pkgname"
}