# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=vc
_pkgname=Vc
pkgver=1.3.3
pkgrel=1
_debver=$pkgver
_debrel=4
pkgdesc='A static library to ease explicit vectorization of C++ code'
url="https://github.com/${_pkgname}Devel/$_pkgname"
arch=(i686 x86_64)
license=(Modified-BSD)
makedepends=(cmake quilt)
source=(https://github.com/${_pkgname}Devel/$_pkgname/releases/download/$pkgver/$_pkgname-$pkgver.tar.gz
        https://deb.debian.org/debian/pool/main/v/vc/vc_$_debver-$_debrel.debian.tar.xz)
sha512sums=('5b4b6711c5244f023f351c9b98b62d02ff2b8c4cd44682ea91c308d82bd1c33278cecea2103bb6220fce06b5d13f907fecfb527002388f664f083a5af0c5877e'
            'e860418742d37609a91c2c5e4010fabe8e687e72f1c5735edf1241709785615dd84f07c51b92598b3843cc84f9be1b733322c8915194b422b9d2c8b5d6ad4c34')

prepare() {
  cd $_pkgname-$pkgver

  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    quilt push -av
  fi
}

build() {
  cmake -B build -S $_pkgname-$pkgver \
    -D CMAKE_INSTALL_PREFIX=/usr \
    -D TARGET_ARCHITECTURE=generic
  make -C build
}

package() {
  make DESTDIR="$pkgdir" -C build install

  # license
  install -Dm644 $_pkgname-$pkgver/LICENSE -t $pkgdir/usr/share/licenses/$pkgname
}