# Maintainer: Jesus E. <heckyel@riseup.net>

_dir=2691
pkgname=vamp-plugin-sdk
pkgver=2.10.0
_debver=2.10.0
_debrel=1
pkgrel=1
pkgdesc='The Vamp audio analysis plug-in system'
arch=('i686' 'x86_64')
url='https://www.vamp-plugins.org/'
license=('Expat' 'Modified-BSD')
depends=('gcc-libs' 'glibc')
makedepends=('libsndfile' 'quilt')
optdepends=('libsndfile: for vamp-simple-host')
source=("https://deb.debian.org/debian/pool/main/v/vamp-plugin-sdk/${pkgname}_${pkgver}.orig.tar.gz"
        "https://deb.debian.org/debian/pool/main/v/vamp-plugin-sdk/vamp-plugin-sdk_${_debver}-${_debrel}.debian.tar.xz")
sha512sums=('153b7f2fa01b77c65ad393ca0689742d66421017fd5931d216caa0fcf6909355fff74706fabbc062a3a04588a619c9b515a1dae00f21a57afd97902a355c48ed'
            '298358212b41ded55643bb099551bd928065f091cbf52e0e1adb0d7c97cbcc03431b762b31bb0e33e2873b500c6abe5cc76be0c2ec17a5c84cf2af7e68190c1b')

prepare() {
  cd "${pkgname}-${pkgver}"
  if [[ ${pkgver%.*} = ${_debver%.*} ]]; then
    # Debian patches
    export QUILT_PATCHES=debian/patches
    export QUILT_REFRESH_ARGS='-p ab --no-timestamps --no-index'
    export QUILT_DIFF_ARGS='--no-timestamps'

    mv "$srcdir"/debian .

    # Doesn't apply
    rm -v debian/patches/02-fix_pkg-config.patch || true

    quilt push -av
  fi
}

build() {
  cd "${pkgname}-${pkgver}"
  ./configure --prefix=/usr
  make
}

package() {
  cd "${pkgname}-${pkgver}"
  make DESTDIR="$pkgdir" install
  # license
  install -vDm 644 COPYING \
    -t "${pkgdir}/usr/share/licenses/${pkgname}/"
  # docs
  install -vDm 644 {CHANGELOG,README} \
    -t "${pkgdir}/usr/share/doc/${pkgname}"
}