# Maintainer: Jesus E. <heckyel@riseup.net>

pkgname=unison
pkgver=2.51.3
pkgrel=2
pkgdesc="File-synchronization tool"
url='https://www.cis.upenn.edu/~bcpierce/unison/'
arch=('i686' 'x86_64')
license=('GPL-3')
options=('!makeflags')
makedepends=('ocaml' 'lablgtk2')
optdepends=('gtk2: graphical interface')
source=("${pkgname}-${pkgver}.tar.gz::https://github.com/bcpierce00/unison/archive/v${pkgver}.tar.gz"
        "unison-large.patch"
        "unison.desktop")
sha512sums=('202bc592cf18d3ac76d7e29ec71add5d6e33a96b4b885e0e2add9a5a621db2290184f268c70e4f05e4884d6cdfed09f6fcd3dde85681c39628a10ea552917c8f'
            'e2f7a5e6e832ee9c694f36e399178652456d2047b22cba86603982cd6f6caf54e520fc87a8bde1940b2da46102cf3aa89f3e062c965efc77cd840b47e01b4d2f'
            '74526b1f583f49b3e1c68b72c9ab3d5875796b8b371c1388cf3b5b25aef8a0304023e9bb960b2ff9aec2eb989f712e99b2c049b8075529074f62ef9ffd6c1cdd')

prepare() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  sed 's/region_of_string/region_of_bytes/' -i src/uigtk2.ml
  patch -p0 -i ../unison-large.patch
}

build() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  for ui in gtk2 text; do
    cp -a . build || true
    pushd build
    export CFLAGS=
    make all UISTYLE=$ui DEBUGGING=false THREADS=true
    mv src/unison src/unison-$ui
    mv src/unison-* ..
    popd
    rm -fr build
  done
}

package() {
  cd "${srcdir}/${pkgname}-${pkgver}"

  install -d "${pkgdir}"/usr/bin
  install -m755 unison-* "${pkgdir}"/usr/bin
  ln -s unison-text "${pkgdir}"/usr/bin/unison

  install -Dm644 ../unison.desktop "${pkgdir}/usr/share/applications/${pkgname}.desktop"
  install -Dm644 icons/U.svg "${pkgdir}/usr/share/icons/hicolor/scalable/apps/${pkgname}.svg"
  for i in 16 24 32 48 256; do
    install -Dm644 icons/U.${i}x${i}x16m.png "${pkgdir}/usr/share/icons/hicolor/${i}x${i}/apps/${pkgname}.png"
  done

  install -Dm644 LICENSE -t "${pkgdir}/usr/share/licenses/$pkgname"
}